ArduinoとCAN通信で制御する振動アクセルペダル（試作）

---------------------中略-------------------------------
// MsTimer2をincludeする
#include "MsTimer2.h"
--------------------------------------------------------
// Motor ONの最大時間(msec)
#define MAX_TIME_MOTOR_ON 600
--------------------------------------------------------
void setup(){　
  // タイマー割り込みの設定
  MsTimer2::set(MAX_TIME_MOTOR_ON, timer_interrapt);
}
--------------------------------------------------------
void loop(){
  if(モーター駆動条件を満たしたら）{
    MsTimer2::start(); //計測タイマスタート
  }
}
--------------------------------------------------------
void timer_interrapt(void){
  // 時間経過フラグしたら、Motor動作準備フラグをOFFする
  flag_Motor_Ready = false;
  // 時間計測タイマを停止する（カウントストップ）
  MsTimer2::stop();
}

/*
 * File:   motor_test.ino
 * Author: 岡本一車
 * https://kurumashikou.com/
*/
// Motor ONの最大時間(msec)
#define MAX_TIME_MOTOR_ON 600
void setup() {
  // シリアルモニタの設定
  SERIAL_PORT_MONITOR.begin(115200);
  // シリアルポートの準備が整うまで待つ
  while(!Serial);
  // 出力ポート設定
  pinMode(10, OUTPUT);
  delay(2000);
  digitalWrite(10, HIGH);
  delay(MAX_TIME_MOTOR_ON);  
  digitalWrite(10, LOW);
  digitalWrite(INDICATOR_PIN, LOW);  
}
// メイン処理 ////////////////////////////////////////////////
void loop() {
}

/*
 * File:   Haptic_feedback_REV_guidance.ino
 * Author: 岡本一車
 * https://kurumashikou.com/
*/
#include <SPI.h>
#include <mcp_can.h>
#include "string.h"
#include "MsTimer2.h"
// S660用にコンパイルするなら1、アルトワークス用なら0を指定
#define S660 1
// S660用の設定 //////////////////////////////////
#if S660
  // S660用LEDを点灯するヒステリシスを設定する
  // LED ONする回転数
  #define RPM_LED_ON 7550
  // LED OFFできる回転数
  #define RPM_LED_OFF 7350
  
  // S660用CANフィルタ設定
  #define MASK0 0x7FF
  // S660 engine_Rev CAN ID 0x1DC
  #define Filter0 0x1DC
  // S660 Transmission_Vel CAN ID 0x158
  #define Filter1 0x158
  #define MASK1 0x7FF
  #define Filter2 0x000
  #define Filter3 0x000
  #define Filter4 0x000
  #define Filter5 0x000
// アルトワークス用の設定 ///////////////////////////
#else
  // HA36S用LEDを点灯するヒステリシスを設定する
  // LED ONする回転数
  #define RPM_LED_ON 7200
  // LED OFFできる回転数
  #define RPM_LED_OFF 7100
  // HA36Sアルトワークス用CANフィルタ設定
  #define MASK0 0x7FF
  // S660 engine_Rev CAN ID 0x124
  #define Filter0 0x124
  // S660 Transmission_Vel CAN ID 0x314
  #define Filter1 0x314
  #define MASK1 0x7FF
  #define Filter2 0x000
  #define Filter3 0x000
  #define Filter4 0x000
  #define Filter5 0x000
// 車種別設定ここまで
#endif
// HapticデバイスをONする回転数とOFFする回転数
// Motor ONする回転数
#define RPM_MOTOR_ON 7550
// Motor を再びReadyにできる回転数
#define RPM_MOTOR_ON_READY 7100
// Motor ONの最大時間(msec)
#define MAX_TIME_MOTOR_ON 600
// ピンの設定
// SS_defaultPin Arduino unoは10, megaは53
// ここではCAN通信用のCSピンとして、digital 9を使用する
const int SPI_CAN_CS_PIN = 9;
// Motor出力ピン
const int MOTOR_PIN = 10;
// 表示用LEDピン
const int INDICATOR_PIN = 8;
// グローバル変数 ///////////////////////////////////////////
// タイムスタンプ用変数
unsigned long timestamp = 0;
unsigned long timestamp_old = 0;
// 受信メッセージ格納用
unsigned long can_ID = 0;
unsigned char len = 0;
unsigned char buf[8] = {0, 0, 0, 0, 0, 0, 0, 0};
// 送信メッセージ格納用
//unsigned char sendMsg[8] = {0, 0, 0, 0, 0, 0, 0, 1};
// 回転数格納用変数
unsigned int rpm = 0;
// 速度格納用変数
unsigned int vel = 0;
// Hapticデバイス作動フラグ
bool motor_ON = false;
// Motor動作準備フラグ
bool flag_Motor_Ready = false;
// CANデータ書き込み値を保持する
String logDataStr; 
// CANトランシーバにCSピン設定をセットし、CAN通信インスタンスを生成
MCP_CAN CAN(SPI_CAN_CS_PIN);
// 割り込み関数の定義
void timer_interrapt(void);
// 初期設定 ////////////////////////////////////////////////
void setup() {
  // シリアルモニタの設定
  SERIAL_PORT_MONITOR.begin(115200);
  // シリアルポートの準備が整うまで待つ
  while(!Serial);
  
  // 出力ポート設定
  pinMode(MOTOR_PIN, OUTPUT);
  pinMode(INDICATOR_PIN, OUTPUT);
  // タイマー割り込みの設定
  MsTimer2::set(MAX_TIME_MOTOR_ON, timer_interrapt);
  // CANの初期設定 ///////////////////////////////////////////////
  if (CAN.begin(MCP_ANY, CAN_500KBPS, MCP_8MHZ) != CAN_OK) {
    SERIAL_PORT_MONITOR.println("CAN-BUS initiliased error ..............");
    while(1);
  }else{
    CAN.setMode(MCP_NORMAL);
    SERIAL_PORT_MONITOR.println("CAN-BUS initiliased OK !!");
  }
  
  // フィルターとマスクの設定。Mask0/Mask2両方の設定が必要
  CAN.init_Mask(0, 0, MASK0);
  CAN.init_Mask(1, 0, MASK1);
  CAN.init_Filt(0, 0, Filter0);
  CAN.init_Filt(1, 0, Filter1);
  CAN.init_Filt(2, 0, Filter2); 
  CAN.init_Filt(3, 0, Filter3);
  CAN.init_Filt(4, 0, Filter4);
  CAN.init_Filt(5, 0, Filter5);
  // Motor動作準備OK
  flag_Motor_Ready = true;
}
// メイン処理 ////////////////////////////////////////////////
void loop() {
  // CANメッセージ受信したときの動作
  if (CAN_MSGAVAIL == CAN.checkReceive()) {
    
    // 受信したデータをシリアルモニタに送信 ////////////////////////////////////
    if(timestamp_old == 0){
      timestamp_old = millis();
    }
    // CANデータを取得
    //CAN.readMsgBufID(&can_ID, &len, buf);
    CAN.readMsgBuf(&can_ID, &len, buf);
    // タイムスタンプの取得
    timestamp = millis() - timestamp_old;
    
// S660の場合の処理
#if S660
    // 回転数を取得(CAN ID 0x1DC)
    if(can_ID==476){
      rpm = buf[1]*256 + buf[2];
      
    // 速度を取得(CAN ID 0x158)
    }else if(can_ID==344){
      vel = buf[4]*256+buf[5];
    }
// アルトワークスの場合の処理
#else
    // 回転数を取得(CAN ID 0x124)
    if(can_ID==292){
      rpm = buf[1]*256 + buf[2];
      rpm = rpm/4;
      
    // 速度を取得(CAN ID 0x314)
    }else if(can_ID==788){
      vel = buf[1]*256+buf[2];
      vel = vel*3/400;
    }
#endif
    // デバッグ用出力
    logDataStr  = "";
    logDataStr += String(rpm);
    logDataStr += String("rpm / ");
    logDataStr += String(vel);
    logDataStr += String("kph");
    logDataStr += "\r\n";
    if(motor_ON){
      logDataStr += String("*********************************************");  
    }
    SERIAL_PORT_MONITOR.print(logDataStr); 
    
  }
  // ON条件 ////////////////////////////////////////////////////////
  // モータがOFF、かつ回転数を超過した、かつ、 Motor動作準備フラグが立っている
  if(!motor_ON && rpm>=RPM_MOTOR_ON && flag_Motor_Ready){
    // モータONする
    motor_ON = true;
    // 時間計測タイマをセットする
    MsTimer2::start();
  }
  
  // OFF条件 ////////////////////////////////////////////////////////
  // ONのまま所定時間が過ぎたらMotor動作準備フラグがOFFされるのでモーターをOFF  
  if(!flag_Motor_Ready){
    // モータOFFする
    motor_ON = false;
  }
  // 再度ON許可する条件 //////////////////////////////////////////////
  // 回転数が指定回転数を下回ったらMotor動作準備フラグを立てることにより、
  // 次回指定回転数超過時に再びMotorをONできる
  if(rpm<=RPM_MOTOR_ON_READY){
    // 時間計測タイマを停止する（カウントストップ）
    MsTimer2::stop();
    // Motor動作準備フラグを立てる
    flag_Motor_Ready = true;
  }
  // 動作フラグが立っているとき、MotorとLEDを表示 /////
  if(motor_ON){
    digitalWrite(MOTOR_PIN, HIGH);
    digitalWrite(INDICATOR_PIN, HIGH);
  }else{
    digitalWrite(MOTOR_PIN, LOW);
    digitalWrite(INDICATOR_PIN, LOW);
  }
}
// タイマ割り込み
void timer_interrapt(void){
  // 時間経過フラグしたら、Motor動作準備フラグをOFFする
  flag_Motor_Ready = false;
  // 時間計測タイマを停止する（カウントストップ）
  MsTimer2::stop();
}