ArduinoとCAN通信で作るレブインジケータ

// S660用にコンパイルするなら1、アルトワークス用なら0を指定
#define S660 1

// S660の場合の処理
#if S660
    // 回転数を取得(CAN ID 0x1DC)
    if(can_ID==476){
      rpm = buf[1]*256 + buf[2];
      
    // 速度を取得(CAN ID 0x158)
    }else if(can_ID==344){
      vel = buf[4]*256+buf[5];
    }
// アルトワークスの場合の処理
#else
    // 回転数を取得(CAN ID 0x124)
    if(can_ID==292){
      rpm = buf[1]*256 + buf[2];
      rpm = rpm/4;
      
    // 速度を取得(CAN ID 0x314)
    }else if(can_ID==788){
      vel = buf[1]*256+buf[2];
      vel = vel*3/400;
    }
#endif

  //#define RPM_LED_ON 7550
  #define RPM_LED_ON 4000
  // LED OFFできる回転数
  //#define RPM_LED_OFF 7100
  #define RPM_LED_OFF 3900

// S660用CANフィルタ設定
  #define MASK0 0x7FF
  // S660 engine_Rev CAN ID 0x1DC
  #define Filter0 0x1DC
  // S660 Transmission_Vel CAN ID 0x158
  #define Filter1 0x158
  #define MASK1 0x7FF
  #define Filter2 0x000
  #define Filter3 0x000
  #define Filter4 0x000
  #define Filter5 0x000
～　中略　～
// フィルターとマスクの設定。Mask0/Mask2両方の設定が必要
  CAN.init_Mask(0, 0, MASK0);
  CAN.init_Mask(1, 0, MASK1);
  CAN.init_Filt(0, 0, Filter0);
  CAN.init_Filt(1, 0, Filter1);
  CAN.init_Filt(2, 0, Filter2); 
  CAN.init_Filt(3, 0, Filter3);
  CAN.init_Filt(4, 0, Filter4);
  CAN.init_Filt(5, 0, Filter5);

/*
 * File:   LED_REV_Indicator.ino
 * Arduino NANO と MCP2515,TJA1050を用いたCAN通信
 * 必要なライブラリ: MCP_CAN Library ⇒ https://github.com/coryjfowler/MCP_CAN_lib
 * Author: 岡本一車
 * https://kurumashikou.com/
*/
#include <SPI.h>
#include <mcp_can.h>
#include "string.h"
#include "MsTimer2.h"
// S660用にコンパイルするなら1、アルトワークス用なら0を指定
#define S660 1
// S660用の設定 //////////////////////////////////
#if S660
  // S660用LEDを点灯するヒステリシスを設定する
  // LED ONする回転数
  //#define RPM_LED_ON 7550
  #define RPM_LED_ON 4000
  // LED OFFできる回転数
  //#define RPM_LED_OFF 7100
  #define RPM_LED_OFF 3900
  
  // S660用CANフィルタ設定
  #define MASK0 0x7FF
  // S660 engine_Rev CAN ID 0x1DC
  #define Filter0 0x1DC
  // S660 Transmission_Vel CAN ID 0x158
  #define Filter1 0x158
  #define MASK1 0x7FF
  #define Filter2 0x000
  #define Filter3 0x000
  #define Filter4 0x000
  #define Filter5 0x000
// アルトワークス用の設定 ///////////////////////////
#else
  // HA36S用LEDを点灯するヒステリシスを設定する
  // LED ONする回転数
  //#define RPM_LED_ON 7550
  #define RPM_LED_ON 4000
  // LED OFFできる回転数
  //#define RPM_LED_OFF 7100
  #define RPM_LED_OFF 3900
  // HA36Sアルトワークス用CANフィルタ設定
  #define MASK0 0x7FF
  // S660 engine_Rev CAN ID 0x124
  #define Filter0 0x124
  // S660 Transmission_Vel CAN ID 0x314
  #define Filter1 0x314
  #define MASK1 0x7FF
  #define Filter2 0x000
  #define Filter3 0x000
  #define Filter4 0x000
  #define Filter5 0x000
// 車種別設定ここまで
#endif
// ピンの設定 OUT
// SS_defaultPin Arduino unoは10, megaは53
// ここではCAN通信用のCSピンとして、digital 9を使用する
const int SPI_CAN_CS_PIN = 9;
// 表示用LEDピン
const int LED_PIN = 8;
// 外部出力ピン
const int OUTPUT_PIN = 10;
// グローバル変数 ///////////////////////////////////////////
// タイムスタンプ用変数
unsigned long timestamp = 0;
unsigned long timestamp_old = 0;
// 受信メッセージ格納用
unsigned long can_ID = 0;
unsigned char len = 0;
unsigned char buf[8] = {0, 0, 0, 0, 0, 0, 0, 0};
// 回転数格納用変数
unsigned int rpm = 0;
// 速度格納用変数
unsigned int vel = 0;
// LED点灯フラグ
bool LED_ON = false;
// CANデータ書き込み値を保持する
String logDataStr; 
// CANトランシーバにCSピン設定をセットし、CAN通信インスタンスを生成
MCP_CAN CAN(SPI_CAN_CS_PIN);
// 初期設定 ////////////////////////////////////////////////
void setup() {
  // シリアルモニタの設定
  SERIAL_PORT_MONITOR.begin(115200);
  // シリアルポートの準備が整うまで待つ
  while(!Serial);
  
  // 出力ポート設定
  pinMode(LED_PIN, OUTPUT);
  pinMode(OUTPUT_PIN, OUTPUT);
  // CANの初期設定 ///////////////////////////////////////////////
  if (CAN.begin(MCP_ANY, CAN_500KBPS, MCP_8MHZ) != CAN_OK) {
    SERIAL_PORT_MONITOR.println("CAN-BUS initiliased error ..............");
    while(1);
  }else{
    CAN.setMode(MCP_NORMAL);
    SERIAL_PORT_MONITOR.println("CAN-BUS initiliased OK !!");
  }
  
  // フィルターとマスクの設定。Mask0/Mask2両方の設定が必要
  CAN.init_Mask(0, 0, MASK0);
  CAN.init_Mask(1, 0, MASK1);
  CAN.init_Filt(0, 0, Filter0);
  CAN.init_Filt(1, 0, Filter1);
  CAN.init_Filt(2, 0, Filter2); 
  CAN.init_Filt(3, 0, Filter3);
  CAN.init_Filt(4, 0, Filter4);
  CAN.init_Filt(5, 0, Filter5);
}
// メイン処理 ////////////////////////////////////////////////
void loop() {
  // CANメッセージ受信したときの動作
  if (CAN_MSGAVAIL == CAN.checkReceive()) {
    
    // 受信したデータをシリアルモニタに送信 ////////////////////////////////////
    if(timestamp_old == 0){
      timestamp_old = millis();
    }
    // CANデータを取得
    //CAN.readMsgBufID(&can_ID, &len, buf);
    CAN.readMsgBuf(&can_ID, &len, buf);
    // タイムスタンプの取得
    timestamp = millis() - timestamp_old;
// S660の場合の処理
#if S660
    // 回転数を取得(CAN ID 0x1DC)
    if(can_ID==476){
      rpm = buf[1]*256 + buf[2];
      
    // 速度を取得(CAN ID 0x158)
    }else if(can_ID==344){
      vel = buf[4]*256+buf[5];
    }
// アルトワークスの場合の処理
#else
    // 回転数を取得(CAN ID 0x124)
    if(can_ID==292){
      rpm = buf[1]*256 + buf[2];
      rpm = rpm/4;
      
    // 速度を取得(CAN ID 0x314)
    }else if(can_ID==788){
      vel = buf[1]*256+buf[2];
      vel = vel*3/400;
    }
#endif
    // デバッグ用出力
    logDataStr  = "";
    logDataStr += String(rpm);
    logDataStr += String("rpm / ");
    logDataStr += String(vel);
    logDataStr += String("kph / ");
    logDataStr += String("LED_flag =");
    logDataStr += String(LED_ON);
    logDataStr += "\r\n";
    SERIAL_PORT_MONITOR.print(logDataStr); 
    
  }
  // ON条件 ////////////////////////////////////////////////////////
  // 回転数を超過し、かつLEDが点灯していない場合
  if(!LED_ON && rpm>=RPM_LED_ON){
    // LEDをONする
    LED_ON = true;
  }
  
  // OFF条件 ////////////////////////////////////////////////////////
  // 指定した回転数以下になり、かつLEDが点灯している場合
  if(LED_ON && rpm<=RPM_LED_OFF){
    // LEDをOFFする
    LED_ON = false;
  }
  
  // 動作フラグが立っているとき、LEDを点灯 /////
  if(LED_ON){
    digitalWrite(LED_PIN, HIGH);
    digitalWrite(OUTPUT_PIN, HIGH);
  }else{
    digitalWrite(LED_PIN, LOW);
    digitalWrite(OUTPUT_PIN, LOW);
  }
}